查看(SKU:RB-01C016)Arduino 网络扩展板的源代码

[[文件:RB-01C016.jpg|500px|缩略图|右]]
==产品概述==
以W5100为核心的Arduino Ethernet网络扩展模块，可以使Arduino成为简单的Web服务器或者通过网络控制读写Arduino的数字和模拟接口等网络应用。可直接使用IDE中的Ethernet库文件便可实现一个简单Web服务器。同时该版本的支持mini SD卡（TF卡）读写，功能强悍，不容错过！该扩展板采用了可堆叠的设计，可直接插到Arduino上，同时我们的其他扩展板也可以插上去。
==规格参数==


==使用方法==
1.将网络扩展板与UNO插接在一起，确保引脚连接正常。<br/>
[[文件:wangluokuozhan1.jpg|500px|有框|居中]]

2.如图所示连接UNO和PC机，下载代码到UNO控制器中<br/>
[[文件:wangluokuozhan2.jpg|500px|有框|居中]]
<pre style='color:blue'>/*
  Web Server
 
 A simple web server that shows the value of the analog input pins.
 using an Arduino Wiznet Ethernet shield. 
 
 Circuit:
 * Ethernet shield attached to pins 10, 11, 12, 13
 * Analog inputs attached to pins A0 through A5 (optional)
 
 created 18 Dec 2009
 by David A. Mellis
 modified 9 Apr 2012
 by Tom Igoe
 
 */

#include <SPI.h>
#include <Ethernet.h>

// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network:
byte mac[] = { 
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
IPAddress ip(192,168,1,177);

// Initialize the Ethernet server library
// with the IP address and port you want to use 
// (port 80 is default for HTTP):
EthernetServer server(80);

void setup() {
 // Open serial communications and wait for port to open:
  Serial.begin(9600);
   while (!Serial) {
    ; // wait for serial port to connect. Needed for Leonardo only
  }


  // start the Ethernet connection and the server:
  Ethernet.begin(mac, ip);
  server.begin();
  Serial.print("server is at ");
  Serial.println(Ethernet.localIP());
}


void loop() {
  // listen for incoming clients
  EthernetClient client = server.available();
  if (client) {
    Serial.println("new client");
    // an http request ends with a blank line
    boolean currentLineIsBlank = true;
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        Serial.write(c);
        // if you've gotten to the end of the line (received a newline
        // character) and the line is blank, the http request has ended,
        // so you can send a reply
        if (c == '\n' && currentLineIsBlank) {
          // send a standard http response header
          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println("Connection: close");  // the connection will be closed after completion of the response
	  client.println("Refresh: 5");  // refresh the page automatically every 5 sec
          client.println();
          client.println("<!DOCTYPE HTML>");
          client.println("<html>");
          // output the value of each analog input pin
          for (int analogChannel = 0; analogChannel < 6; analogChannel++) {
            int sensorReading = analogRead(analogChannel);
            client.print("analog input ");
            client.print(analogChannel);
            client.print(" is ");
            client.print(sensorReading);
            client.println("<br />");       
          }
          client.println("</html>");
          break;
        }
        if (c == '\n') {
          // you're starting a new line
          currentLineIsBlank = true;
        } 
        else if (c != '\r') {
          // you've gotten a character on the current line
          currentLineIsBlank = false;
        }
      }
    }
    // give the web browser time to receive the data
    delay(1);
    // close the connection:
    client.stop();
    Serial.println("client disonnected");
  }
}
</pre>

3.将网络扩展板使用网线与电脑连接<br/>
[[文件:wangluokuozhan3.jpg|500px|有框|居中]]

4.设置本地计算机的网络<br/>
[[文件:wangluokuozhan4.jpg|400px|有框|居中]]

5.设置后W5100网络扩展板板载的4个LED会亮起，如果没有请按下复位按钮<br/>
[[文件:wangluokuozhan5.jpg|400px|有框|居中]]

6.现在读出W5100网络扩展板的IP地址<br/>
[[文件:wangluokuozhan6.jpg|700px|有框|居中]]

7.通过电脑可以访问W5100网络扩展板<br/>
[[文件:wangluokuozhan7.jpg|700px|有框|居中]]

==应用例程==
Arduino Ethernet网络扩展模块与Arduino UNO 控制器
[[文件:RB-01C0161.jpg|500px|缩略图|居中]]
Arduino Ethernet网络扩展模块与Arduino MEGA2560控制器
[[文件:RB-01C0163.jpg|500px|缩略图|居中]]

==产品相关推荐==
购买地址：[http://www.alsrobot.cn/goods-219.html Arduino 网络扩展板]