查看SKU:RB-02S020A DS18B20数字温度传感器的源代码

<br/>
[[文件:02S020A01.jpg|500px|有框|右]]
==产品概述==
最新推出的DS18B20数字温度传感器采用美国DALLAS公司生产的DS18B20一总线数字温度感测元件其测温范围 －55℃～＋125℃，固有测温分辨率0.5℃，支持多点组网功能，多个DS18B20可以并联在唯一的三线上，实现多点测温，测量结果以9~12位数字量方式串行传送。 DS18B20数字温度传感器可在各种单片机控制器上应用，尤其在Arduino控制器上更为简单，现成库函数调用，即可完成温度测量，通过3P传感器连接线插接到Arduino专用传感器扩展板上，可以非常容易地实现与环境温度感知相关的互动作品。
==规格参数==
# 类型：数字模块（一总线接口）
# 可用于检测周围空气温度
# 温度测量范围：－55℃～＋125℃
# 测量精度：±0.5 °C（-10 °C至+85 °C范围内）
# 9位～12位A/D转换精度
# 分辨率：0.5℃
# 供电电压：3.3V或5V
8. 产品尺寸图：<br/>
[[文件:size026.jpg|500px|缩略图|居中]]

9.接口定义<br/>
:S：输出信号
:+：电源(VCC)
:-：地(GND)

==工作原理==
DS18B20 是一款常用的数字温度传感器，DS18B20 主要由 64 位光刻 ROM、温度传感器、非挥发的温度报警触发器 TH 和 TL、配置寄存器等四部分组成，具有体积小，使用方便，抗干扰能力强，精度高等特点，适用于各种狭小空间数字测温和控制领域。<br/>
DS18B20 提供9位（二进制）温度读数来表示所测的温度值，采用单线接口，使用时，仅需要一条口线即可实现与单片机的双向通信，简化了分布式温度传感器的应用。在使用中不需要任何外围元件，且支持多点组网的功能，多个 DS18B20 可以并联在唯一的三线上，最多可并联8个，实现多点测温。温度测量范围是 -55 - +125℃，固有测温分辨率为 ±0.5℃，可在 1 秒内把温度变换成数字信号输出。<br/>
DS18B20 有两种供电方式，即数据总线供电方式与外部供电方式，采用数据总线供电虽然可以节省一根导线，但完成温度测量的时间较长；采取外部供电方式虽然多用了一根导线，但是测量速度较快，可以根据实际需求选择供电方式。<br/> 

==编程原理==
数字温度传感器模块引出三个接口，包含有数据线 S，电源 Vcc 和地线 GND，实际应用时，可以将数据线 S 端与 Arduino 控制器的数字引脚连接，如 D2，Arduino 专门提供了可供调用的库函数，该函数的文件名分别为 DallasTemperature 和 OneWire，。通过分别在程序中引用 DallasTemperature.h 和 OneWire.h，并分别实例化对象 OneWire 和 Sensor 类，直接使用类的成员函数来实现数字传感器的温度采集。

==使用方法==
===example1_Arduino===
*主要硬件
:Arduino UNO 控制器
:传感器扩展板V5.0
:DS18B20 温度传感器模块
:通用3P传感器连接线 
:USB 数据通信线 

* 硬件连接
[[文件:02S020A100.png|700px|有框|居中]]

* 例子程序
<pre style='color:blue'>
#include <OneWire.h>
#include <DallasTemperature.h>
 
// 定义DS18B20数据口连接arduino的2号IO上
#define ONE_WIRE_BUS 2
 
// 初始连接在单总线上的单总线设备
OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature sensors(&oneWire);
 
void setup(void)
{
  // 设置串口通信波特率
  Serial.begin(9600);
  Serial.println("Dallas Temperature IC Control Library Demo");
 
  // 初始库
  sensors.begin();
}
 
void loop(void)
{ 
  Serial.print("Requesting temperatures...");
  sensors.requestTemperatures(); // 发送命令获取温度
  Serial.println("DONE");
   
  Serial.print("Temperature for the device 1 (index 0) is: ");
  Serial.println(sensors.getTempCByIndex(0));  
}
 </pre>
* 程序效果
[[文件:02S020A03.png|500px|有框|居中]]

===example2_Arduino===
*主要硬件
:Arduino UNO 控制器
:传感器扩展板V5.0
:DS18B20 温度传感器模块
:通用3P传感器连接线 
:USB 数据通信线 

* 硬件连接
[[文件:02S020A101.png|700px|有框|居中]]

* 例子程序
<pre style='color:blue'>
#include <OneWire.h>
OneWire  ds(10);  // 连接arduino10引脚
void setup(void) {
  Serial.begin(9600);
}
void loop(void) {
  byte i;
  byte present = 0;
  byte type_s;
  byte data[12];
  byte addr[8];
  float celsius, fahrenheit;  
  if ( !ds.search(addr)) {
    Serial.println("No more addresses.");
    Serial.println();
    ds.reset_search();
    delay(250);
    return;
  }  
  Serial.print("ROM =");
  for( i = 0; i < 8; i++) {
    Serial.write(' ');
    Serial.print(addr[i], HEX);
  }
 
  if (OneWire::crc8(addr, 7) != addr[7]) {
      Serial.println("CRC is not valid!");
      return;
  }
  Serial.println();
  
  // the first ROM byte indicates which chip
  switch (addr[0]) {
    case 0x10:
      Serial.println("  Chip = DS18S20");  // or old DS1820
      type_s = 1;
      break;
    case 0x28:
      Serial.println("  Chip = DS18B20");
      type_s = 0;
      break;
    case 0x22:
      Serial.println("  Chip = DS1822");
      type_s = 0;
      break;
    default:
      Serial.println("Device is not a DS18x20 family device.");
      return;
  } 
 
  ds.reset();
  ds.select(addr);
  ds.write(0x44,1);         // start conversion, with parasite power on at the end
   
  delay(1000);     // maybe 750ms is enough, maybe not
  // we might do a ds.depower() here, but the reset will take care of it.
   
  present = ds.reset();
  ds.select(addr);    
  ds.write(0xBE);         // Read Scratchpad
 
  Serial.print("  Data = ");
  Serial.print(present,HEX);
  Serial.print(" ");
  for ( i = 0; i < 9; i++) {           // we need 9 bytes
    data[i] = ds.read();
    Serial.print(data[i], HEX);
    Serial.print(" ");
  }
  Serial.print(" CRC=");
  Serial.print(OneWire::crc8(data, 8), HEX);
  Serial.println();
  // convert the data to actual temperature
  unsigned int raw = (data[1] << 8) | data[0];
  if (type_s) {
    raw = raw << 3; // 9 bit resolution default
    if (data[7] == 0x10) {
      // count remain gives full 12 bit resolution
      raw = (raw & 0xFFF0) + 12 - data[6];
    }
  } else {
    byte cfg = (data[4] & 0x60);
    if (cfg == 0x00) raw = raw << 3;  // 9 bit resolution, 93.75 ms
    else if (cfg == 0x20) raw = raw << 2; // 10 bit res, 187.5 ms
    else if (cfg == 0x40) raw = raw << 1; // 11 bit res, 375 ms
    // default is 12 bit resolution, 750 ms conversion time
  }
  celsius = (float)raw / 16.0;
  fahrenheit = celsius * 1.8 + 32.0;
  Serial.print("  Temperature = ");
  Serial.print(celsius);
  Serial.print(" Celsius, ");   
  Serial.print(fahrenheit);
  Serial.println(" Fahrenheit");
}
 </pre>

* 程序效果
[[文件:02S020A04.png|500px|有框|居中]]

==应用视频==
[[File:wen du 01.png|400px|左|link=http://v.youku.com/v_show/id_XODg0ODMzNzAw.html?from=y1.7-2]]
[[File:wen du 02.png|400px|居中|link=http://v.youku.com/v_show/id_XNDkxNjQ2NDAw.html?from=y1.7-2]]
<br/>
==产品相关推荐==
[[文件:erweima.png|230px|无框|右]]
===资料下载===
网盘链接： https://pan.baidu.com/s/1jTDC5TGtImxm29o0HOtwrw 
提取码：t8vz
===购买地址===
[http://www.alsrobot.cn/goods-161.html  DS18B20 数字温度传感器]<br/>
===周边产品推荐===
[http://www.alsrobot.cn/goods-72.html Arduino DHT11 温度传感器]
<br/>
[http://www.alsrobot.cn/goods-71.html LM35 线性温度传感器 ]<br/>
[http://www.alsrobot.cn/goods.php?id=46 土壤湿度传感器 ]
===相关问题解答===
[http://www.makerspace.cn/forum.php?mod=viewthread&tid=4240&fromuid=10780 DS18B20 数字温度传感器数据波动异常]
===相关学习资料===
[http://www.makerspace.cn/forum.php?mod=viewthread&tid=5339&fromuid=10780 Adafruit 的树莓派教程 DS18B20温度传感器]<br/>
[http://www.makerspace.cn/portal.php 奥松机器人技术论坛]