“(SKU:RB-02S020)DS18B20数字温度传感器”的版本间的差异

2015年6月28日 (日) 21:10的版本

产品概述

2014年最新推出的DS18B20数字温度传感器采用美国DALLAS公司生产的DS18B20一总线数字温度感测元件其测温范围 －55℃～＋125℃，固有测温分辨率0.5℃，支持多点组网功能，多个DS18B20可以并联在唯一的三线上，实现多点测温，测量结果以9~12位数字量方式串行传送。 DS18B20数字温度传感器可在各种单片机控制器上应用，尤其在Arduino控制器上更为简单，现成库函数调用，即可完成温度测量，通过3P传感器连接线插接到Arduino专用传感器扩展板上，可以非常容易地实现与环境温度感知相关的互动作品。

规格参数

1. 类型：数字模块（一总线接口）
2. 可用于检测周围空气温度
3. 温度测量范围：－55℃～＋125℃
4. 测量精度：±0.5 °C（-10 °C至+85 °C范围内）
5. 9位～12位A/D转换精度
6. 分辨率：0.5℃
7. 供电电压：3.3V或5V

使用方法

引脚定义

• S：输出信号
• +：电源(VCC)
• -：地(GND)

应用例程

我们使用Arduino控制器来做个测试，要用到硬件设备如下：

1. Arduino控制器×1
2. Arduino 传感器扩展板×1
3. DS18B20 温度传感器模块×1
4. 通用3P传感器连接线×1
5. USB 数据通信线×1

如图所示，使用传感器连接线将DS18B20 温度传感器连接到Arduino传感器扩展板的数字接口。先把下载的库文件解压缩到你的Arduino安装目录下的hardware\libraries 里面。然后将代码编译后下载到Arduino里，就可以在串口助手窗口上显示测得的当前值。

库文件下载：DS18B20库文件

示例1

实物接线图

#include <OneWire.h>
#include <DallasTemperature.h>
 
// 定义DS18B20数据口连接arduino的2号IO上
#define ONE_WIRE_BUS 2
 
// 初始连接在单总线上的单总线设备
OneWire oneWire(ONE_WIRE_BUS);
DallasTemperature sensors(&oneWire);
 
void setup(void)
{
  // 设置串口通信波特率
  Serial.begin(9600);
  Serial.println("Dallas Temperature IC Control Library Demo");
 
  // 初始库
  sensors.begin();
}
 
void loop(void)
{ 
  Serial.print("Requesting temperatures...");
  sensors.requestTemperatures(); // 发送命令获取温度
  Serial.println("DONE");
   
  Serial.print("Temperature for the device 1 (index 0) is: ");
  Serial.println(sensors.getTempCByIndex(0));  
}
 

示例代码2

实物接线图

#include <OneWire.h>
OneWire  ds(10);  // 连接arduino10引脚
 
void setup(void) {
  Serial.begin(9600);
}
 
void loop(void) {
  byte i;
  byte present = 0;
  byte type_s;
  byte data[12];
  byte addr[8];
  float celsius, fahrenheit;
   
  if ( !ds.search(addr)) {
    Serial.println("No more addresses.");
    Serial.println();
    ds.reset_search();
    delay(250);
    return;
  }
   
  Serial.print("ROM =");
  for( i = 0; i < 8; i++) {
    Serial.write(' ');
    Serial.print(addr[i], HEX);
  }
 
  if (OneWire::crc8(addr, 7) != addr[7]) {
      Serial.println("CRC is not valid!");
      return;
  }
  Serial.println();
  
  // the first ROM byte indicates which chip
  switch (addr[0]) {
    case 0x10:
      Serial.println("  Chip = DS18S20");  // or old DS1820
      type_s = 1;
      break;
    case 0x28:
      Serial.println("  Chip = DS18B20");
      type_s = 0;
      break;
    case 0x22:
      Serial.println("  Chip = DS1822");
      type_s = 0;
      break;
    default:
      Serial.println("Device is not a DS18x20 family device.");
      return;
  } 
 
  ds.reset();
  ds.select(addr);
  ds.write(0x44,1);         // start conversion, with parasite power on at the end
   
  delay(1000);     // maybe 750ms is enough, maybe not
  // we might do a ds.depower() here, but the reset will take care of it.
   
  present = ds.reset();
  ds.select(addr);    
  ds.write(0xBE);         // Read Scratchpad
 
  Serial.print("  Data = ");
  Serial.print(present,HEX);
  Serial.print(" ");
  for ( i = 0; i < 9; i++) {           // we need 9 bytes
    data[i] = ds.read();
    Serial.print(data[i], HEX);
    Serial.print(" ");
  }
  Serial.print(" CRC=");
  Serial.print(OneWire::crc8(data, 8), HEX);
  Serial.println();
 
  // convert the data to actual temperature
 
  unsigned int raw = (data[1] << 8) | data[0];
  if (type_s) {
    raw = raw << 3; // 9 bit resolution default
    if (data[7] == 0x10) {
      // count remain gives full 12 bit resolution
      raw = (raw & 0xFFF0) + 12 - data[6];
    }
  } else {
    byte cfg = (data[4] & 0x60);
    if (cfg == 0x00) raw = raw << 3;  // 9 bit resolution, 93.75 ms
    else if (cfg == 0x20) raw = raw << 2; // 10 bit res, 187.5 ms
    else if (cfg == 0x40) raw = raw << 1; // 11 bit res, 375 ms
    // default is 12 bit resolution, 750 ms conversion time
  }
  celsius = (float)raw / 16.0;
  fahrenheit = celsius * 1.8 + 32.0;
  Serial.print("  Temperature = ");
  Serial.print(celsius);
  Serial.print(" Celsius, ");   
  Serial.print(fahrenheit);
  Serial.println(" Fahrenheit");
}
 

程序效果

下载程序后可以通过Arduino软件的串口查看DS18B20检测的环境温度。

产品相关推荐

购买地址: DS18B20数字温度传感器
论坛地址：奥松机器人技术论坛