(SKU:RB-01C016)Arduino 网络扩展板

产品概述

以W5100为核心的Arduino Ethernet网络扩展模块，可以使Arduino成为简单的Web服务器或者通过网络控制读写Arduino的数字和模拟接口等网络应用。可直接使用IDE中的Ethernet库文件便可实现一个简单Web服务器。同时该版本的支持mini SD卡（TF卡）读写，功能强悍，不容错过！该扩展板采用了可堆叠的设计，可直接插到Arduino上，同时我们的其他扩展板也可以插上去。

规格参数

W5100特性

支持SPI接口(SCS、SCLK、MISO、MOSI)，接线方便，程序简单；
支持硬件TCP/IP协议栈，支持TCP,UDP,ICMP,IGMP,IPv4，ARP,PPPoE.
内嵌10BaseT/100BaseTX以太网物理层；
支持自动通信握手(全双工和半双工)；
端口支持3种工作模式(客户端、服务端、UDP)；
支持4个独立端口同时运行；
内部集成16KBYTE收发缓存；
支持自动极性转换（DMI/MDIX）；

W5100优势

W5100硬件集成TCP/IP协议栈、MAC、PHY，减少了用户代码量、减轻了CPU的压力，而相对便宜的ENC28J60只集成MAC和PHY，TCP/IP协议栈须要用户在上层代码中实现；
W5100可以通过SPI接口控制，只须要操作少量的寄存器即可，大量节约了开发时间.
W5100是通过SPI发指令、数据操作寄存器，不同平台移植W5100的程序更加方便、简单；

使用方法

接线方法

1.将网络扩展板与UNO插接在一起，确保引脚连接正常。

2.如图所示连接UNO和PC机，下载代码到UNO控制器中

例子程序

/*
  Web Server
 
 A simple web server that shows the value of the analog input pins.
 using an Arduino Wiznet Ethernet shield. 
 
 Circuit:
 * Ethernet shield attached to pins 10, 11, 12, 13
 * Analog inputs attached to pins A0 through A5 (optional)
 
 created 18 Dec 2009
 by David A. Mellis
 modified 9 Apr 2012
 by Tom Igoe
 
 */

#include <SPI.h>
#include <Ethernet.h>

// Enter a MAC address and IP address for your controller below.
// The IP address will be dependent on your local network:
byte mac[] = { 
  0xDE, 0xAD, 0xBE, 0xEF, 0xFE, 0xED };
IPAddress ip(192,168,1,177);

// Initialize the Ethernet server library
// with the IP address and port you want to use 
// (port 80 is default for HTTP):
EthernetServer server(80);

void setup() {
 // Open serial communications and wait for port to open:
  Serial.begin(9600);
   while (!Serial) {
    ; // wait for serial port to connect. Needed for Leonardo only
  }


  // start the Ethernet connection and the server:
  Ethernet.begin(mac, ip);
  server.begin();
  Serial.print("server is at ");
  Serial.println(Ethernet.localIP());
}


void loop() {
  // listen for incoming clients
  EthernetClient client = server.available();
  if (client) {
    Serial.println("new client");
    // an http request ends with a blank line
    boolean currentLineIsBlank = true;
    while (client.connected()) {
      if (client.available()) {
        char c = client.read();
        Serial.write(c);
        // if you've gotten to the end of the line (received a newline
        // character) and the line is blank, the http request has ended,
        // so you can send a reply
        if (c == '\n' && currentLineIsBlank) {
          // send a standard http response header
          client.println("HTTP/1.1 200 OK");
          client.println("Content-Type: text/html");
          client.println("Connection: close");  // the connection will be closed after completion of the response
	  client.println("Refresh: 5");  // refresh the page automatically every 5 sec
          client.println();
          client.println("<!DOCTYPE HTML>");
          client.println("<html>");
          // output the value of each analog input pin
          for (int analogChannel = 0; analogChannel < 6; analogChannel++) {
            int sensorReading = analogRead(analogChannel);
            client.print("analog input ");
            client.print(analogChannel);
            client.print(" is ");
            client.print(sensorReading);
            client.println("<br />");       
          }
          client.println("</html>");
          break;
        }
        if (c == '\n') {
          // you're starting a new line
          currentLineIsBlank = true;
        } 
        else if (c != '\r') {
          // you've gotten a character on the current line
          currentLineIsBlank = false;
        }
      }
    }
    // give the web browser time to receive the data
    delay(1);
    // close the connection:
    client.stop();
    Serial.println("client disonnected");
  }
}

3.将网络扩展板使用网线与电脑连接